How can I limit bandwidth usage in Bitcoin-qt client?

Question

I've just finished the intial blockchain download/verify in my BitcoinQt client (17 hours..) and I now see that BitcoinQt is happily eating all of my upstream bandwidth. (About 110kByte/sec on my ADSL line.)

I'm going to be applying bandwidth limits to the app using Waterroof, which should probably work --

But shouldn't there be a built-in method for BitcoinQt to be more polite about its bandwidth consumption?

Answer 1

If your goal is just to get a stable Bitcoin node running, and not to contribute to the network, you can add listen=0 to your bitcoin.conf file. This generally (though not always) keeps your upload bandwidth in check.

If you want to contribute to the Bitcoin network without using up too much of your own bandwidth, however, there are ways of limiting your upload speed for Bitcoin Core (Bitcoin-qt) only. Instructions depend on your OS, so what follows is a breakdown on what to do with each OS.

IMPORTANT NOTE: If you limit the bandwidth of Bitcoin Core far below your actual upload speed, it can actually harm the Bitcoin network instead of helping it. To be a responsible maintainer of the Bitcoin network, you should test your upload speed and then set your outgoing bandwidth limit to be as close to your actual speed as possible (e.g. 90%). This guide is intended solely for people whose internet connections go unresponsive due to Bitcoin Core completely saturating their upload bandwidth.

The following instructions are abridged from this article I wrote recently: https://www.maxlaumeister.com/blog/how-to-limit-bandwidth-of-bitcoin-core-on-windows-mac-os-and-linux/

---

Limiting Bitcoin Bandwidth on Windows

1. Download and Install NetBalancer.

2. Start Bitcoin Core if it isn’t already running.

3. Run NetBalancer.

4. Find “bitcoin-qt.exe” in the list of running applications in the NetBalancer dialog and double-click it to change its bandwidth rules.

5. Under “Upload Priority” choose “Limited”, set the maximum amount of bandwidth for Bitcoin Core to use, and confirm.

You’re done! NetBalancer will now sit in the background and make sure Bitcoin Core doesn’t use more bandwidth than you want it to.

---

Limiting Bandwidth on Mac OS X

OS X 10.10 Yosemite and later

For OS X 10.10 Yosemite and later, there is no easy way to limit the bandwidth of a particular application, but the overall system bandwidth can be limited as follows:

1. Visit Apple Developer Downloads and log in with your Apple ID.

2. Search for “Hardware IO Tools for Xcode” and download the latest stable (non-beta) version.

3. Open the .dmg and double-click “Network Link Conditioner.prefpane” to install the prefpane. From now on, you can enable/disable Network Link Conditioner from System Preferences.

4. From the Network Link Conditioner pane in System Preferences, click “Manage Profiles”, then click the “+” button to add a new profile.

5. Edit the profile and add your desired maximum upload speed.

6. Save your edit, exit the profile manager, choose your new profile, and flip the big switch to enable the limiter.

Mac OS will place an icon in your notification tray so you remember that it’s on. Unlike the Windows/Linux solutions, this will limit the bandwidth for your entire system, so be sure to turn it off you’re not running Bitcoin Core.

OS X 10.9 Mavericks and earlier

For OS X 10.9 Mavericks you can use IceFloor to configure bandwidth rules. For 10.8 Mountain Lion and earlier, use Waterroof. Alternatively, if you want a simple way to control the overall system bandwidth limit instead of just Bitcoin Core, follow the instructions above for OS X 10.10 Yosemite and later.

---

Limiting Bandwidth on Linux

1. Make sure you have tc installed by typing tc at the command line. If you get “command not found”, install tc using your favorite package manager. If you're on a Debian-based distribution, the easiest way to install tc is by using apt-get:

   sudo apt-get update

   sudo apt-get install iproute2

2. Download the tc.sh script from the official Bitcoin Core repository using wget:

   wget https://raw.githubusercontent.com/bitcoin/bitcoin/master/contrib/qos/tc.sh

3. Open the script in a text editor. Find the line that says IF="eth0" and change eth0 to reflect the network interface that your internet connection runs through. To get a list of your computer's network interfaces, use ifconfig on the command line. My computer is connected wirelessly through wlan1, so the IF line of my tc.sh looks like this:

   IF="wlan1"

4. LINKCEIL should reflect the limit of the network interface, and most likely does not need to be changed.

   LINKCEIL="1gbit"

5. Change LIMIT to be the maximum bandwidth you want Bitcoin Core to use (I chose 1mbit). If you don’t have any other Bitcoin Core nodes in your local network, you can delete the line that says LOCALNET. This line is there to make a bandwidth exception for port 8333 communications within your local network (i.e. not out to the internet).

   LIMIT="1mbit"

   Leave the rest of the commands in tc.sh alone unless you know what you're doing. The final top section of my tc.sh ended up looking like this:

   #network interface on which to limit traffic
   IF="wlan1"
   
   #limit of the network interface in question
   LINKCEIL="1gbit"
   
   #limit outbound Bitcoin protocol traffic to this rate
   LIMIT="1mbit"
   

6. Exit your editor and make the script executable with the following command:

   chmod +x ./tc.sh

7. Run the script as superuser:

   sudo ./tc.sh

   Your Bitcoin Core bandwidth will be throttled until you reboot your computer!

Optionally, you can set the script to run every time you start your computer. Instructions for running scripts on boot will vary depending on your Linux distribution. On Ubuntu, one of the ways to run a script on boot is by adding the script to your /etc/rc.local file.

Conclusion

Hopefully this post was helpful in showing you how to limit the bandwidth of Bitcoin Core! For the full version, including images and extra information, check out the original article here.

Answer 2

One answer mentioned in the thread is to add

listen=0

to your bitcoin.conf (which is in {User}\AppData\Roaming\Bitcoin).

This stops other nodes connecting to you to download the blockchain, hence stopping the large upstream bandwidth consumption

Answer 3

If your bitcoin client is running on a dedicated linux machine you might want to try wondershaper. It allows you to limit the bandwith of your network adapter. For instance

sudo wondershaper eth0 1024 56

limits your bandwith to 1024 Kbps download and 56 Kbps upload rate.

sudo wondershaper -c eth0

clears interface limits and brings you back to full speed.

Answer 4

You can use maxuploadtarget by adding a line like:

maxuploadtarget=5000

to the bitcoin.conf file in your .bitcoin directory. The example above will set a daily soft upload limit of ~5GB/day.

Even better might be limiting the maxconnections with

maxconnections=25

Below is a Perl script I have written that will run on Linux, and will automatically limit the maximum number of connections (and thus bandwidth) during the day, and then once nighttime rolls around, it will remove the connection/bandwidth restrictions. This way, while you are asleep, your Bitcoin full node can be making the most of your bandwidth, and when you're awake, the full node won't interfere with your web browsing during the day.

 #!/usr/bin/perl
 use warnings;
 use strict;
 
 #############################################################################################################
 #Program purpose: To configure a Bitcoin full node so bandwidth use is restricted during the day.
 #
 #How it works: The bitcoin.conf file is periodically modified so that Bitcoin runs with fewer connections
 #during the day (using less bandwidth), and unlimited connections (higher bandwidth) at night.
 #
 #How to run: On Linux, run within the Bitcoin /bin directory (i.e. the directory holding 'bitcoind').
 #############################################################################################################
 
 #Set the path of Bitcoin's bitcoin.conf file here:
 my $path_of_bitcoin_conf_file = $ENV{"HOME"} . "/.bitcoin/bitcoin.conf";
 my $bitcoind_connection_max = 25; # The maximum number of connections for bitcoind to make during day hours.
 my $start_of_day_hour = 7; # 7 am.
 my $start_of_night_hour = 21; # 9 pm in 24 hour format.
 
 my $time_period_last = "hasn't been recorded yet"; #Records whether the last time check was "day" or "night".
 
 #Run indefinitely, configuring node bandwidth restrictions based on time of day.
 while (1) {
     my $time_period_current = night_or_day();
     #When the day becomes night or night becomes day, configure bitcoin bandwidth accordingly.
     if ( $time_period_last ne $time_period_current ) {
         modify_bitcoin_conf_file($time_period_current);
         restart_bitcoind();
     }
     else{} #Night/day hasn't changed, check again in another minute.
     $time_period_last = $time_period_current;
     sleep 60;
 }
 
 #Modify bitcoin.conf to limit bandwidth during the day, but unlimited during the night.
 sub modify_bitcoin_conf_file {
     my $night_or_day = shift;
     my $last_line_of_bitcoin_conf_file;
     if ($night_or_day eq "night"){
         $last_line_of_bitcoin_conf_file = ""; #No maxconnections limit at night.
     }
     elsif ($night_or_day eq "day"){
         $last_line_of_bitcoin_conf_file = "maxconnections=$bitcoind_connection_max\n";
     }
     else{die "Error, no night or day\n";}
 
     #Check that bitcoin.conf exists and then open it for editing.
     if (-e $path_of_bitcoin_conf_file){
         open (my $bitcoin_conf_fh, "<", $path_of_bitcoin_conf_file);
         my @bitcoin_conf = <$bitcoin_conf_fh>;
         close $bitcoin_conf_fh;
         open ($bitcoin_conf_fh, ">", $path_of_bitcoin_conf_file);
         foreach my $line (@bitcoin_conf){
             print $bitcoin_conf_fh $line unless $line =~ m/maxconnections/;
         }
         print $bitcoin_conf_fh $last_line_of_bitcoin_conf_file;
         close $bitcoin_conf_fh;
         print "The bitcoin.conf file has been changed to $night_or_day settings ", scalar localtime, "\n";
     }
     else {
         die "Could not locate the bitcoin.conf file: '$path_of_bitcoin_conf_file'\n";
     }
 }
 
 sub restart_bitcoind {
     shut_down_bitcoin_if_running();
     start_bitcoind();
 }
 
 sub shut_down_bitcoin_if_running {
     #Check if Bitcoin is running.
     if ( bitcoind_is_running() ){
         print "Bitcoin daemon is running, trying to shut down now. ", scalar localtime, "\n";
         shut_down_bitcoind();
     }
     else{
         print "Bitcoin daemon is not running at the moment. ", scalar localtime, "\n";
     }
 }
 
 sub shut_down_bitcoind {
     if ( program_running("./bitcoin-cli stop", "Bitcoin server stopping") ){
         sleep 10;
         #Verify bitcoind process has stopped.
         while ( bitcoind_is_running() ) {
             print "Still waiting for Bitcoin daemon to shut down. ", scalar localtime, "\n";
             sleep 10;
         }
         print "Bitcoin daemon successfully shut down. ", scalar localtime, "\n";
     }
     else{
         print "Having problems shutting down Bitcoin daemon. ", scalar localtime, "\n";
     }
 }
 
 sub bitcoind_is_running {
     if ( program_running("ps -e", "bitcoind") ){
         return 1;
     }
     else{
         return 0;
     }
 }
 
 sub start_bitcoind {
     unless ( system("./bitcoind -daemon") ){
         print "Bitcoin server booting up. ", scalar localtime, "\n";
         sleep 30;
         #Verify Bitcoin server has fully booted.
         until ( bitcoin_server_is_up() ) {
             print "Still waiting for Bitcoin server to fully load. ", scalar localtime, "\n";
             sleep 60;
 
         }
         print "Bitcoin server has successfully loaded. ", scalar localtime, "\n";
     }
     else{
         print "Having problems starting the Bitcoin daemon. ", scalar localtime, "\n";
     }
 }
 
 sub bitcoin_server_is_up {
     #If we can get a block count, then the server is booted.
     if ( program_running("./bitcoin-cli getblockcount", '^\d{6,}') ){
         return 1;
     }
     else{
         return 0;
     }
 }
 
 #Call a program with argument 1, and return true if its stdout matches argument 2.
 sub program_running {
     my ($shell_cmd, $stdout_match) = @_;
     open (my $prog_call, "-|", $shell_cmd);
     while (my $stdout = <$prog_call>){
         if ($stdout =~ m/$stdout_match/){
             return 1;
         }
         else{} #Keep searching for match.
     }
     return 0; #Match not found.
 }
 
 #Determine if it's nighttime or daytime.
 sub night_or_day {
     my @current_time = localtime();
     my $current_hour = $current_time[2];
     if ($current_hour >= $start_of_day_hour && $current_hour < $start_of_night_hour){
         return "day";
     }
     else {
         return "night";
     }
 }